FreeDOS での開発にまつわる etc.

5. 呼出規約について

呼出規約 (calling convention) はサブルーチンの呼び出し方を定めたもので ABI の一部です。具体的にはパラメータの渡し方や計算結果の受け取り方等を定めます。

普段高級言語だけでプログラムを書いている場合全く気にしないレイヤの話ですが、今回のようにアセンブリ言語でサブルーチンを記述する場合は必要になる知識です。呼び出し規約を統一すれば自作のアセンブリ言語で書いたサブルーチンから C の関数を呼べたりその逆も可能になります。

x86 においてメジャーな呼出規約は cdecl と呼ばれるものです。この解説としてネット上で見つかるものでは Guide to x86 Assembly の Calling Convention 項がわかりやすくまとめられていて参考になると思います。

簡単な例として 2 つの int 型の和を計算して返す関数をアセンブリ言語で定義し、C から呼んでみます。

add.asm:

.486

_TEXT segment byte public use16 'CODE'
      assume cs:_TEXT

;; int add(int x, int y)
public _add
_add proc near
     push bp         ; (1)
     mov  bp,sp      ; (1)
     mov  ax,[bp+4]  ; [bp+4] = parameter x (2)
     add  ax,[bp+6]  ; [bp+6] = parameter y (2)
     pop  bp         ; (1)
     ret
_add endp

_TEXT ends
      end

main.c:

#include <stdio.h>

int add(int x, int y);

void main(void)
{
  int res;

  res = add(2, 4);
  printf("res = %d\n", res);
}

実行結果:

> wasm -ms -d1 add.asm
> wcl -ecc -ms -d3 main.c add.obj
> main.exe
res = 6

呼出規約ではサブルーチンの呼び出し側 (caller) と呼ばれる側 (callee) それぞれに守るべきルールを定めています。そうしたものの一つとしてサブルーチン呼出前後で保持すべきレジスタというのがあり、保持すべきレジスタについて caller はサブルーチン前後でその値が変更されないと想定できる一方で、保持されないレジスタについては必要であれば自分で別途値を保存しておく必要があります。 add.asm の (1) では、はじめに bp レジスタの値を push し、最後に pop することでサブルーチン呼出前後で変えてはならない bp レジスタの値を保持しています。

サブルーチン内部では本処理を始める前に mov bp,sp で bp レジスタの値を上書いていますが、これにより higher address には return address, 関数のパラメータが並び、lower address にはローカル変数が並ぶといった感じになるのでパラメータへのアクセスの見通しがよくなります。

実際に wd で mov bp,sp 実行前のスタック、レジスタの状態を見ると以下のようになります。

命令実行後は [bp] (0B52h) で旧 bp の値 (OB5Eh)、 [bp+2] (0B54h) で return address (002Dh)、 [bp+4] (0B56h) で引数 x の値である 2, [bp+6] (0B58h) で引数 y の値である 4 にアクセスできることがわかります。 add.asm 内 (2) でも示しましたがサブルーチンへのパラメータは C の関数定義でいう右から順にスタックに積まれています。

最後に cdecl ではサブルーチンの返り値を ax レジスタにセットするので [bp+4] , [bp+6] の add した結果を ax レジスタにセットしています。

もう一つローカル変数や si, di レジスタを使用する例を見てみます。 si, di は bp と同様 callee が呼び出し前後で保持すべきレジスタです。ここでは addp という 2 つの int * を受け取り、それらが指す整数と 1 を足した結果を返すという関数を定義します。なおここでは例として使用するために多少冗長な実装をしています。

addp.asm:

.486

_TEXT segment byte public use16 'CODE'
      assume cs:_TEXT

;; int addp(int *x, int *y)
public _addp
_addp proc near
      push bp
      mov  bp,sp
      sub  sp,2              ;; Allocate space for local variable
      push di                ;; Store di register
      push si                ;; Store si register

      mov  word ptr [bp-2],1 ;; size directive is necessary
      mov  ax,[bp-2]

      mov  si,[bp+4]
      mov  di,[bp+6]
      add  ax,[si]
      add  ax,[di]

      pop  si                ;; Restore si register
      pop  di                ;; Restore di register
      mov  sp, bp            ;; Deallocate local variable
      pop  bp
      ret
_addp endp

_TEXT ends
      end

main.c:

#include <stdio.h>

int addp(int *x, int *y);

void main(void)
{
  int res, a, b;

  a = 4;
  b = 9;
  res = addp(&a, &b);
  printf("res = %d\n", res);
}

実行:

> wasm -ms -d1 addp.asm
> wcl -ecc -ms -d3 main.c addp.obj
> main.exe
res = 14

始めに bp レジスタの保存とセットを行うというのは add サブルーチンと同様ですが、addp ではそのあとにローカル変数格納用のスペースや保持すべき di, si レジスタの値をスタックに格納しています。

mov word ptr [bp-2],1 実行後のスタックの状態は以下のようになります。 [bp-2] に 0001h, [bp-4] に di レジスタの値 036Ch、 [bp-6] に si レジスタの値 0372h が保存されています。

また関数のパラメータ x, y としては 0B5Ah, 0B5Ch が渡されており、 ds レジスタの 16FAh から 16FA:0B5A, 16FA:0B5C の指すメモリ番地を見に行くと、それぞれ 4, 9 という想定通りの値が渡されていることがわかります。

ちなみにポインタのサイズですが 2 bytes なのは small model でコンパイルしているためだと思います。small model ではプログラム中でセグメントレジスタの値が変更されないのでポインタとしては offset 2 bytes 分あれば任意のメモリ番地を特定することができます。逆に言えばセグメントレジスタが固定とは限らない large model ではポインタとして 4 bytes (segment 2bytes, offset 2 bytes) 必要なはずで、実際に試してみると確かにそのようになっています。

#include <stdio.h>

void main(void)
{
  printf("size of ptr: %d\n", sizeof(int *));
  printf("size of __far ptr: %d\n", sizeof(int __far *));
}

# compile for small model
> wcl -ecc -ms ptr_size.c
> ptr_size.exe
size of ptr: 2
size of __far ptr: 4

# compile for large model
> wcl -ecc -ls ptr_size.c
> ptr_size.exe
size of ptr: 4
size of __far ptr: 4

例外として small model でも上のように __far キーワードをつけると segment 2 bytes を含めた 4 bytes のサイズになるようです。以下のコードを small model でコンパイルし、check 呼出直後のスタックを見ると、nearX は offset のみの 2bytes (0064h), farY は segment を含めた 4 bytes (1546h:0062h) が積まれていることがわかります。

main.c:

#include <stdio.h>
#include <dos.h>

int x, y;
int __far *z;

void check(int *nearX, int __far *farY);

void main(void)
{
  struct SREGS seg;

  segread(&seg);
  x = 1;
  y = 2;
  z = MK_FP(seg.ds, (unsigned short) (&y));
  check(&x, z);
}

check.asm:

_TEXT segment byte public use16 'CODE'
      assume cs:_TEXT

;; void check(int *nearX, int __far *farY)
public _check
_check proc near
       ret       ;; do nothing
_check encp

_TEXT ends
      end

実行:

> wasm -ms -d1 check.asm
> wcl -ecc -ms -d3 main.c check.obj
> wd main.exe

参考:

• 呼出規約 - Wikipedia
• Guide to x86 Assembly

#include <stdio.h>

int doAdd(int x, int y);
int doAdd2(int x, int y);
int (*f)(int, int);

int add(int x, int y)
{
  return x + y;
}

void main(void)
{
  int ret;

  f = add;
  ret = doAdd(5, 9);
  printf("ret = %d\n", ret);
  ret = doAdd2(6, 10);
  printf("ret = %d\n", ret);
}

.486

_BSS segment byte public use16 'BSS'
      assume ds:_DATA

extrn _f:word ;; 2 bytes variable defined in elsewhere

_BSS ends

_TEXT segment byte public use16 'CODE'
      assume cs:_TEXT

extrn _add:near ;; _add exists in the same segment

;; int doAdd(int x, int y)
public _doAdd
_doAdd proc near
       push bp
       mov  bp,sp

       mov  ax,[bp+4]
       mov  cx,[bp+6]
       push cx
       push ax
       call _add

       mov  sp,bp
       pop  bp
       ret
_doAdd endp

public _doAdd2
_doAdd2 proc near
        push bp
        mov  bp,sp

        mov  ax,[bp+4]
        mov  cx,[bp+6]
        push cx
        push ax
        call _f

        mov  sp,bp
        pop  bp
        ret
_doAdd2 endp

_TEXT ends
      end

> wasm -ms -d1 main_a.asm
> wcl -ecc -ms -d3 main.c main_a.obj
> main.exe
ret = 14
ret = 16